Моделирование всего усилителя с использованием макромоделей

.lib nom.lib

.inc ScriptMM109.txt

 

.param Vdc=45m Vac=45m Vsin=45m Rv=200 Vin2=0

.param Rc=16.5k Ccor=1p

.param Rb=1k N=10 N0=3 Re1=4k Re2=0.02k Re3=0.5k

.param Rsl=0.01k

 

V1 pls 0 15

V2 mns 0 -15

Vin in1 0 {Vdc} AC {Vac} sin 0 {Vsin} 1k

Rv out 0 {Rv}

 

Xda pls in1 n1 n2 in2 DA

+ params: Rc={Rc} Ccor={Ccor}

Vin2 in2 0 {Vin2}

Xsl pls n1 n3 SL

+ params: Rsl={Rsl}

Xcs1 n2 mns CS

+params: Rb={Rb} N={N} N0={N0} Re={Re1}

Xcs2 n3 mns CS

+params: Rb={Rb} N={N} N0={N0} Re={Re2}

Xer pls n3 mns out ER

+ params: Re={Re3}

 

*DA TUNINGS

*.DC Vin 0 32m 0.1m

*.step param Ida 0.1m 2m 0.01m

*.step param Rc 1k 50k 0.5k

*.AC DEC 100 0.1 10k

*.tran 1m 14m 10m 10u

 

 

*ER TUNINGS

*.DC Vsl -2 2 0.1

*.DC param Rsl 0.1k 10k 0.1k

 

 

*SL TUNINGS

*.DC param Re2 0.5k 5k 0.1k

 

*CS TUNINGS

*.DC param N 1 20 0.1

*.DC param N0 1 20 0.1

*.DC param Re 0.1 50k 0.1k

 

*MAIN TUNINGS

*.AC DEC 50 1k 10meg

*.step dec param Ccor 0.1p 1n 20

*.tran 1m 14m 10m 10u

 

 

*DA PROBES

.probe IB(Xda.q1) IB(Xda.q2) VB(Xda.q1)

+VC(Xda.q1) VC(Xda.q2) VE(Xda.q1) VB(Xda.q2)

 

*ER PROBES

.probe VE(Xer.q1) VB(Xer.q1)

 

*SL PROBES

.probe V([n3])

 

*CS PROBES

.probe VB(Xcs1.q1) IC(Xcs1.q1)

 

*MAIN PROBES

.probe V([out]) V([in1])

 

.end

 

Описание схем в файле ScriptMM109.txt

.model Q2N2857 NPN(Is=69.28E-18 Xti=3 Eg=1.11 Vaf=100 Bf=288 dev/gauss 20% Ne=1.167

+ Ise=69.28E-18 Ikf=21.59m Xtb=1.5 Br=1.219 Nc=2 Isc=0 Ikr=0 Rc=4

+ Cjc=893.1f Mjc=.3017 Vjc=.75 Fc=.5 Cje=939.8f Mje=.3453 Vje=.75

+ Tr=1.607n Tf=115.7p Itf=.27 Vtf=10 Xtf=30 Rb=10)

.MODEL Rt RES(R=1 dev/gauss 5% TC1=3e-4)

 

.subckt DA pls in1 sl cs in2

+ params: Rc=16.5k Ccor=1p

q1 sl in1 cs Q2N2857

q2 c2 in2 cs Q2N2857

Rc1 sl pls Rt {Rc}

Rc2 c2 pls Rt {Rc}

Ccor sl pls {Ccor}

.ends

 

.subckt SL pls da ercs

+ params: Rsl=0.01k

q1 pls da e1 Q2N2857

Rslc e1 ercs {Rsl}

.ends

 

.subckt CS dasl mns

+params: Rb=1k N=10 N0=3 Re=1k

q1 dasl b1 e1 Q2N2857

q2 bc bc mns Q2N2857

Rb1 bc b1 Rt {N0*Rb}

Rb2 b1 dasl Rt {N0*N*Rb}

Re e1 mns Rt {Re}

.ends

 

.subckt ER pls sl mns out

+ params: Re=0.5k

q1 pls sl out Q2N2857

Re1 out mns Rt {Re}

.ends

Коррекция АЧХ.

С помощью развертки параметра Ccor с основной директивой AC определим его значение, при котором обеспечивается требование варианта в области ВЧ.

Занесём дополнительные директивы

.AC DEC 50 1k 10meg

.step dec param Ccor 0.1p 1n 20

и в режиме РА воспользуемся EGF LPBW(V(out),2.8).

 

Рис.25. – График для определения Сcor.

 

 

С помощью курсора определяем, что на частоте 1 МГц, Ccor

 

Проведём окончательную проверку смоделированного устройства в режиме TRAN. С помощью этого режима выведем осциллограмму выходного сигнала. Она выглядит следующим образом:

Рис.26. – Осциллограмма выходного сигнала.

Из полученной осциллограммы в режиме TRAN видим, чтоV_OUT = 0 приV_IN = 0, а также V_OUT = V_OUT.MAX= 1,8В, что удовлетворяет требованиям КР.

 

 

Заключение

В данной курсовой работе было проведено моделирование интегрального усилителя тока на биполярных транзисторах. Были вычислены необходимые номиналы для активных и реактивных элементов схемы для обеспечения заданного коэффициента усиления и входного сопротивления.

Таким образом, смоделированный усилитель удовлетворяет всем требуемым параметрам. Все поставленные цели и задачи полностью выполнены.