Теоретический материал. Язык оболочки командной строки (shell language) в Windows реализован в виде командных (или

 

Язык оболочки командной строки (shell language) в Windows реализован в виде командных (или пакетных) файлов. Командный файл в Windows ‑ это обычный текстовый файл с расширением bat или cmd, в котором записаны допустимые команды операционной системы (как внешние, так и внутренние), а также некоторые дополнительные инструкции и ключевые слова, придающие командным файлам некоторое сходство с алгоритмическими языками программирования. Например, если записать в файл deltmp.bat следующие команды:

 

C:\

CD %TEMP%

DEL /F *.tmp

 

и запустить его на выполнение (аналогично исполняемым файлам с расширением com или exe), то мы удалим все файлы во временной директории Windows. Таким образом, исполнение командного файла приводит к тому же результату, что и последовательный ввод записанных в нем команд. При этом не проводится никакой предварительной компиляции или проверки синтаксиса кода; если встречается строка с ошибочной командой, то она игнорируется. Очевидно, что если вам приходится часто выполнять одни и те же действия, то использование командных файлов может сэкономить много времени.

 

Вывод сообщений и дублирование команд

 

По умолчанию команды пакетного файла перед исполнением выводятся на экран, что выглядит не очень эстетично. С помощью команды ECHO OFF можно отключить дублирование команд, идущих после нее (сама команда ECHO OFF при этом все же дублируется). Например,

 

REM Следующие две команды будут дублироваться на экране …

DIR C:\

ECHO OFF

REM А остальные уже не будут

DIR D:\

 

Для восстановления режима дублирования используется команда ECHO ON. Кроме этого, можно отключить дублирование любой отдельной строки в командном файле, написав в начале этой строки символ @, например:

 

ECHO ON

REM Команда DIR C:\ дублируется на экране

DIR C:\

REM А команда DIR D:\ — нет

@DIR D:\

 

Таким образом, если поставить в самое начало файла команду

 

@ECHO OFF

 

то это решит все проблемы с дублированием команд.

 

В пакетном файле можно выводить на экран строки с сообщениями. Делается это с помощью команды

 

ECHO сообщение

 

Например,

 

@ECHO OFF

ECHO Привет!

Команда ECHO. (точка должна следовать

непосредственно за словом "ECHO")

выводит на экран пустую строку. Например,

@ECHO OFF

ECHO Привет!

ECHO.

ECHO Пока!

 

Часто бывает удобно для просмотра сообщений, выводимых из пакетного файла, предварительно полностью очистить экран командой CLS.

 

Используя механизм перенаправления ввода/вывода (символы > и >>), можно направить сообщения, выводимые командой ECHO, в определенный текстовый файл. Например:

 

@ECHO OFF

ECHO Привет! > hi.txt

ECHO Пока! >> hi.txt

 

С помощью такого метода можно, скажем, заполнять файлы-протоколы с отчетом о произведенных действиях. Например:

 

@ECHO OFF

REM Попытка копирования

XCOPY C:\PROGRAMS D:\PROGRAMS /s

REM Добавление сообщения в файл report.txt в случае

REM удачного завершения копирования

IF NOT ERRORLEVEL 1 ECHO Успешное копирование >> report.txt

 

Использование параметров командной строки

 

При запуске пакетных файлов в командной строке можно указывать произвольное число параметров, значения которых можно использовать внутри файла. Это позволяет, например, применять один и тот же командный файл для выполнения команд с различными параметрами.

 

Для доступа из командного файла к параметрам командной строки применяются символы %0, %1, …, %9 или %*. При этом вместо %0 подставляется имя выполняемого пакетного файла, вместо %1, %2, …, %9 ‑ значения первых девяти параметров командной строки соответственно, а вместо %* ‑ все аргументы. Если в командной строке при вызове пакетного файла задано меньше девяти параметров, то «лишние» переменные из %1 ‑ %9 замещаются пустыми строками. Рассмотрим следующий пример. Пусть имеется командный файл copier.bat следующего содержания:

 

@ECHO OFF

CLS

ECHO Файл %0 копирует каталог %1 в %2

XCOPY %1 %2 /S

 

Если запустить его из командной строки с двумя параметрами, например

 

copier.bat C:\Programs D:\Backup

 

то на экран выведется сообщение

 

Файл copier.bat копирует каталог C:\Programs в D:\Backup

 

и произойдет копирование каталога C:\Programs со всеми его подкаталогами в D:\Backup.

 

При необходимости можно использовать более девяти параметров командной строки. Это достигается с помощью команды SHIFT, которая изменяет значения замещаемых параметров с %0 по %9, копируя каждый параметр в предыдущий, то есть значение %1 копируется в %0, значение %2 ‑ в %1 и т.д. Замещаемому параметру %9 присваивается значение параметра, следующего в командной строке за старым значением %9. Если же такой параметр не задан, то новое значение %9 ‑ пустая строка.

 

Рассмотрим пример. Пусть командный файл my.bat вызван из командной строки следующим образом:

 

my.bat p1 p2 p3

 

Тогда %0=my.bat, %1=p1, %2=p2, %3=p3, параметры %4 ‑ %9 являются пустыми строками. После выполнения команды SHIFT значения замещаемых параметров изменятся следующим образом: %0=p1, %1=p2, %2=p3, параметры %3 ‑ %9 ‑ пустые строки.

 

При включении расширенной обработки команд SHIFT поддерживает ключ /n, задающий начало сдвига параметров с номера n, где n может быть числом от 0 до 9.

Например, в следующей команде:

 

SHIFT /2

 

параметр %2 заменяется на %3, %3 на %4 и т.д., а параметры %0 и %1 остаются без изменений.

 

Команда, обратная SHIFT (обратный сдвиг), отсутствует. После выполнения SHIFT уже нельзя восстановить параметр (%0), который был первым перед сдвигом. Если в командной строке задано больше десяти параметров, то команду SHIFT можно использовать несколько раз.

 

В командных файлах имеются некоторые возможности синтаксического анализа заменяемых параметров. Для параметра с номером n (%n) допустимы синтаксические конструкции (операторы), представленные в таблице 1.

 

Таблица 1. Операторы для заменяемых параметров

Параметр	Описание
%~Fn	Переменная %n расширяется до полного имени файла
%~Dn	Из переменной %n выделяется только имя диска
%~Pn	Из переменной %n выделяется только путь к файлу
%~Nn	Из переменной %n выделяется только имя файла
%~Xn	Из переменной %n выделяется расширение имени файла
%~Sn	Значение операторов N и X для переменной %n изменяется так, что они работают с кратким именем файла
%~$PATH:n	Проводится поиск по каталогам, заданным в переменной среды PATH, и переменная %n заменяется на полное имя первого найденного файла. Если переменная PATH не определена или в результате поиска не найден ни один файл, эта конструкция заменяется на пустую строку. Естественно, здесь переменную PATH можно заменить на любое другое допустимое значение

 

Данные синтаксические конструкции можно объединять друг с другом, например:

 

%~DPn ‑ из переменной %n выделяется имя диска и путь,

 

%~NXn ‑ из переменной %n выделяется имя файла и расширение.

 

Рассмотрим следующий пример. Пусть мы находимся в каталоге C:\TEXT и запускаем пакетный файл с параметром Рассказ.doc (%1=Рассказ.doc). Тогда применение операторов, описанных в таблице 1, к параметру %1 даст следующие результаты:

 

%~F1=C:\TEXT\Рассказ.doc

%~D1=C:

%~P1=\TEXT\

%~N1=Рассказ

%~X1=.doc

%DP1=C:\TEXT\

%NX1=Рассказ.doc

 

Работа с переменными среды

 

Внутри командных файлов можно работать с так называемыми переменными среды (или переменными окружения), каждая из которых хранится в оперативной памяти, имеет свое уникальное имя, а ее значением является строка. Стандартные переменные среды автоматически инициализируются в процессе загрузки операционной системы. Такими переменными являются, например, WINDIR, которая определяет расположение каталога Windows, TEMP, которая определяет путь к каталогу для хранения временных файлов Windows или PATH, в которой хранится системный путь (путь поиска), то есть список каталогов, в которых система должна искать выполняемые файлы или файлы совместного доступа (например, динамические библиотеки). Кроме того, в командных файлах с помощью команды SET можно объявлять собственные переменные среды.

 

Получение значения переменной

 

Для получения значения определенной переменной среды нужно имя этой переменной заключить в символы %. Например:

 

@ECHO OFF

CLS

REM Создание переменной MyVar

SET MyVar=Привет

REM Изменение переменной

SET MyVar=%MyVar%!

ECHO Значение переменной MyVar: %MyVar%

REM Удаление переменной MyVar

SET MyVar=

ECHO Значение переменной WinDir: %WinDir%

 

При запуске такого командного файла на экран выведется строка

 

Значение переменной MyVar: Привет!

Значение переменной WinDir: C:\WINDOWS

 

Преобразования переменных как строк

 

С переменными среды в командных файлах можно производить некоторые манипуляции. Во-первых, над ними можно производить операцию конкатенации (склеивания). Для этого нужно в команде SET просто написать рядом значения соединяемых переменных. Например,

 

SET A=Раз

SET B=Два

SET C=%A%%B%

 

После выполнения в файле этих команд значением переменной C будет являться строка 'РазДва'. Не следует для конкатенации использовать знак +, так как он будет воспринят просто в качестве символа. Например, после запуска файл следующего содержания

 

SET A=Раз

SET B=Два

SET C=A+B

ECHO Переменная C=%C%

SET D=%A%+%B%

ECHO Переменная D=%D%

 

на экран выведутся две строки:

 

Переменная C=A+B

Переменная D=Раз+Два

 

Во-вторых, из переменной среды можно выделять подстроки с помощью конструкции %имя_переменной:~n1,n2%, где число n1 определяет смещение (количество пропускаемых символов) от начала (если n1 положительно) или от конца (если n1 отрицательно) соответствующей переменной среды, а число n2 ‑ количество выделяемых символов (если n2 положительно) или количество последних символов в переменной, которые не войдут в выделяемую подстроку (если n2 отрицательно). Если указан только один отрицательный параметр -n, то будут извлечены последние n символов. Например, если в переменной хранится строка «21.09.2007» (символьное представление текущая дата при определенных региональных настройках), то после выполнения следующих команд

 

SET dd1=%DATE:~0,2%

SET dd2=%DATE:~0,-8%

SET mm=%DATE:~-7,2%

SET yyyy=%DATE:~-4%

 

новые переменные будут иметь такие значения: %dd1%=21, %dd2%=21, %mm%=09, %yyyy%=2007.

 

В-третьих, можно выполнять процедуру замены подстрок с помощью конструкции %имя_переменной:s1=s2% (в результате будет возвращена строка, в которой каждое вхождение подстроки s1 в соответствующей переменной среды заменено на s2). Например, после выполнения команд

 

SET a=123456

SET b=%a:23=99%

 

в переменной b будет храниться строка «199456». Если параметр s2 не указан, то подстрока s1 будет удалена из выводимой строки, т.е. после выполнения команды

 

SET a=123456

SET b=%a:23=%

 

в переменной b будет храниться строка «1456».

 

Операции с переменными как с числами

 

При включенной расширенной обработке команд (этот режим в Windows XP используется по умолчанию) имеется возможность рассматривать значения переменных среды как числа и производить с ними арифметические вычисления. Для этого используется команда SET с ключом /A. Приведем пример пакетного файла add.bat, складывающего два числа, заданных в качестве параметров командной строки, и выводящего полученную сумму на экран:

 

@ECHO OFF

REM В переменной M будет храниться сумма

SET /A M=%1+%2

ECHO Сумма %1 и %2 равна %M%

REM Удалим переменную M

SET M=

 

Локальные изменения переменных

 

Все изменения, производимые с помощью команды SET над переменными среды в командном файле, сохраняются и после завершения работы этого файла, но действуют только внутри текущего командного окна. Также имеется возможность локализовать изменения переменных среды внутри пакетного файла, то есть автоматически восстанавливать значения всех переменных в том виде, в каком они были до начала запуска этого файла. Для этого используются две команды: SETLOCAL и ENDLOCAL. Команда SETLOCAL определяет начало области локальных установок переменных среды. Другими словами, изменения среды, внесенные после выполнения SETLOCAL, будут являться локальными относительно текущего пакетного файла. Каждая команда SETLOCAL должна иметь соответствующую команду ENDLOCAL для восстановления прежних значений переменных среды. Изменения среды, внесенные после выполнения команды ENDLOCAL, уже не являются локальными относительно текущего пакетного файла; их прежние значения не будут восстановлены по завершении выполнения этого файла.

 

Связывание времени выполнения для переменных

 

При работе с составными выражениями (группы команд, заключенных в круглые скобки) нужно учитывать, что переменные среды в командных файлах используются в режиме раннего связывания. С точки зрения логики выполнения командного файла это может привести к ошибкам. Например, рассмотрим командный файл 1.bat со следующим содержимым:

 

SET a=1

ECHO a=%a%

SET a=2

ECHO a=%a%

 

и командный файл 2.bat:

 

SET a=1

ECHO a=%a%

(SET a=2

ECHO a=%a% )

 

Казалось бы, результат выполнения этих двух файлов должен быть одинаковым: на экран выведутся две строки: «a=1» и «a=2». На самом же деле таким образом сработает только файл 1.bat, а файл 2.bat два раза выведет строку «a=1»!

Данную ошибку можно обойти, если для получения значения переменной вместо знаков процента (%) использовать восклицательный знак (!) и предварительно включить режим связывания времени выполнения командой SETLOCAL ENABLEDELAYEDEXPANSION. Таким образом, для корректной работы файл 2.bat должен иметь следующий вид:

 

SETLOCAL ENABLEDELAYEDEXPANSION

SET a=1

ECHO a=%a%

(SET a=2

ECHO a=!a! )

 

Приостановка выполнения командных файлов

 

Для того, чтобы вручную прервать выполнение запущенного bat-файла, нужно нажать клавиши <Ctrl>+<C> или <Ctrl>+<Break>. Однако часто бывает необходимо программно приостановить выполнение командного файла в определенной строке с выдачей запроса на нажатие любой клавиши. Это делается с помощью команды PAUSE. Перед запуском этой команды полезно с помощью команды ECHO информировать пользователя о действиях, которые он должен произвести. Например:

 

ECHO Вставьте дискету в дисковод A: и нажмите любую клавишу

PAUSE

 

Команду PAUSE обязательно нужно использовать при выполнении потенциально опасных действий (удаление файлов, форматирование дисков и т.п.). Например,

 

ECHO Сейчас будут удалены все файлы в C:\Мои документы!

ECHO Для отмены нажмите Ctrl-C

PAUSE

DEL "C:\Мои документы\*.*"

 

Вызов внешних командных файлов

 

Из одного командного файла можно вызвать другой, просто указав его имя. Например:

 

@ECHO OFF

CLS

REM Вывод списка log-файлов

DIR C:\*.log

REM Передача выполнения файлу f.bat

f.bat

COPY A:\*.* C:\

PAUSE

 

Однако в этом случае после выполнения вызванного файла управление в вызывающий файл не передается, то есть в приведенном примере команда

 

COPY A:\*.* C:\

 

(и все следующие за ней команды) никогда не будет выполнена.

 

Для того, чтобы вызвать внешний командный файл с последующим возвратом в первоначальный файл, нужно использовать специальную команду

 

CALL файл

Например:

@ECHO OFF

CLS

REM Вывод списка log-файлов

DIR C:\*.log

REM Передача выполнения файлу f.bat

CALL f.bat

COPY A:\*.* C:\

PAUSE

 

В этом случае после завершения работы файла f.bat управление вернется в первоначальный файл на строку, следующую за командой CALL (в нашем примере это команда COPY A:\*.* C:\).

 

Операторы перехода

 

Командный файл может содержать метки и команды GOTO перехода к этим меткам. Любая строка, начинающаяся с двоеточия :, воспринимается при обработке командного файла как метка. Имя метки задается набором символов, следующих за двоеточием до первого пробела или конца строки. Приведем пример.

 

Пусть имеется командный файл следующего содержания:

 

@ECHO OFF

COPY %1 %2

GOTO Label1

ECHO Эта строка никогда не выполнится

:Label1

REM Продолжение выполнения

DIR %2

После того, как в этом файле мы доходим до команды

GOTO Label1

его выполнение продолжается со строки

REM Продолжение выполнения

 

В команде перехода внутри файла GOTO можно задавать в качестве метки перехода строку :EOF, которая передает управление в конец текущего пакетного файла (это позволяет легко выйти из пакетного файла без определения каких-либо меток в самом его конце).

Также для перехода к метке внутри текущего командного файла кроме команды GOTO можно использовать и рассмотренную выше команду CALL:

 

CALL :метка аргументы

 

При вызове такой команды создается новый контекст текущего пакетного файла с заданными аргументами, и управление передается на инструкцию, расположенную сразу после метки. Для выхода из такого пакетного файла необходимо два раза достичь его конца. Первый выход возвращает управление на инструкцию, расположенную сразу после строки CALL, а второй выход завершает выполнение пакетного файла. Например, если запустить с параметром «Копия-1» командный файл следующего содержания:

 

@ECHO OFF

ECHO %1

CALL :2 Копия-2

:2

ECHO %1

 

то на экран выведутся три строки:

 

Копия-1

Копия-2

Копия-1

 

Таким образом, подобное использование команды CALL очень похоже на обычный вызов подпрограмм (процедур) в алгоритмических языках программирования.

 

Операторы условия

 

С помощью команды IF … ELSE (ключевое слово ELSE может отсутствовать) в пакетных файлах можно выполнять обработку условий нескольких типов. При этом если заданное после IF условие принимает истинное значение, система выполняет следующую за условием команду (или несколько команд, заключенных в круглые скобки), в противном случае выполняется команда (или несколько команд в скобках), следующие за ключевым словом ELSE.

 

Проверка значения переменной

 

Первый тип условия используется обычно для проверки значения переменной. Для этого применяются два варианта синтаксиса команды IF:

 

IF [NOT] строка1==строка2 команда1 [ELSE команда2]

 

(квадратные скобки указывают на необязательность заключенных в них параметров) или

 

IF [/I] [NOT] строка1 оператор_сравнения строка2 команда

 

Рассмотрим сначала первый вариант. Условие строка1==строка2 (здесь необходимо писать именно два знака равенства) считается истинным при точном совпадении обеих строк. Параметр NOT указывает на то, что заданная команда выполняется лишь в том случае, когда сравниваемые строки не совпадают.

Строки могут быть литеральными или представлять собой значения переменных (например, %1 или %TEMP%). Кавычки для литеральных строк не требуются. Например,

 

IF %1==%2 ECHO Параметры совпадают!

IF %1==Петя ECHO Привет, Петя!

 

Отметим, что при сравнении строк, заданных переменными, следует проявлять определенную осторожность. Дело в том, что значение переменной может оказаться пустой строкой, и тогда может возникнуть ситуация, при которой выполнение командного файла аварийно завершится. Например, если вы не определили с помощью команды SET переменную MyVar, а в файле имеется условный оператор типа

 

IF %MyVar%==C:\ ECHO Ура!!!

 

то в процессе выполнения вместо %MyVar% подставится пустая строка и возникнет синтаксическая ошибка. Такая же ситуация может возникнуть, если одна из сравниваемых строк является значением параметра командной строки, так как этот параметр может быть не указан при запуске командного файла. Поэтому при сравнении строк нужно приписывать к ним в начале какой-нибудь символ, например:

 

IF -%MyVar%==-C:\ ECHO Ура!!!

 

С помощью команд IF и SHIFT можно в цикле обрабатывать все параметры командной строки файла, даже не зная заранее их количества. Например, следующий командный файл (назовем его primer.bat) выводит на экран имя запускаемого файла и все параметры командной строки:

 

@ECHO OFF

ECHO Выполняется файл: %0

ECHO.

ECHO Файл запущен со следующими параметрами...

REM Начало цикла

:BegLoop

IF -%1==- GOTO ExitLoop

ECHO %1

REM Сдвиг параметров

SHIFT

REM Переход на начало цикла

GOTO BegLoop

:ExitLoop

REM Выход из цикла

ECHO.

ECHO Все.

 

Если запустить primer.bat с четырьмя параметрами:

 

primer.bat А Б В Г

 

то в результате выполнения на экран выведется следующая информация:

 

Выполняется файл: primer.bat

 

Файл запущен со следующими параметрами:

А

Б

В

Г

 

Все.

 

Рассмотрим теперь оператор IF в следующем виде:

 

IF [/I] строка1 оператор_сравнения строка2 команда

 

Синтаксис и значение операторов_сравнения представлены в таблице 2.

 

Таблица 2. Операторы сравнения в IF

Параметр	Значение
EQL	Равно
NEQ	Не равно
LSS	Меньше
LEQ	Меньше или равно
GTR	Больше
GEQ	Больше или равно

 

Приведем пример использования операторов сравнения:

 

@ECHO OFF

CLS

IF -%1 EQL –Вася ECHO Привет, Вася!

IF -%1 NEQ –Вася ECHO Привет, но Вы не Вася!

 

Ключ /I, если он указан, задает сравнение текстовых строк без учета регистра. Ключ /I можно также использовать и в форме строка1==строка2 команды IF. Например, условие

 

IF /I DOS==dos …

 

будет истинным.

 

Проверка существования заданного файла

 

Второй способ использования команды IF ‑ это проверка существования заданного файла. Синтаксис для этого случая имеет вид:

 

IF [NOT] EXIST файл команда1 [ELSE команда2]

 

Условие считается истинным, если указанный файл существует. Кавычки для имени файла не требуются. Приведем пример командного файла, в котором с помощью такого варианта команды IF проверяется наличие файла, указанного в качестве параметра командной строки.

 

@ECHO OFF

IF -%1==- GOTO NoFileSpecified

IF NOT EXIST %1 GOTO FileNotExist

 

REM Вывод сообщения о найденном файле

ECHO Файл '%1' успешно найден.

GOTO :EOF

 

:NoFileSpecified

REM Файл запущен без параметров

ECHO В командной строке не указано имя файла.

GOTO :EOF

 

:FileNotExist

REM Параметр командной строки задан, но файл не найден

ECHO Файл '%1' не найден.

 

Проверка наличия переменной среды

 

Аналогично файлам команда IF позволяет проверить наличие в системе определенной переменной среды:

 

IF DEFINED переменная команда1 [ELSE команда2]

 

Здесь условие DEFINED применяется подобно условию EXISTS наличия заданного файла, но принимает в качестве аргумента имя переменной среды и возвращает истинное значение, если эта переменная определена. Например:

 

@ECHO OFF

CLS

IF DEFINED MyVar GOTO :VarExists

ECHO Переменная MyVarне определена

GOTO :EOF

:VarExists

ECHO Переменная MyVarопределена,

ECHO ее значение равно %MyVar%

 

Проверка кода завершения предыдущей команды

 

Еще один способ использования команды IF ‑ это проверка кода завершения (кода выхода) предыдущей команды. Синтаксис для IF в этом случае имеет следующий вид:

 

IF [NOT] ERRORLEVEL число команда1 [ELSE команда2]

 

Здесь условие считается истинным, если последняя запущенная команда или программа завершилась с кодом возврата, равным либо превышающим указанное число.

Составим, например, командный файл, который бы копировал файл my.txt на диск C: без вывода на экран сообщений о копировании, а в случае возникновения какой-либо ошибки выдавал предупреждение:

 

@ECHO OFF

XCOPY my.txt C:\ > NUL

REM Проверка кода завершения копирования

IF ERRORLEVEL 1 GOTO ErrOccurred

ECHO Копирование выполнено без ошибок.

GOTO :EOF

 

:ErrOccurred

ECHO При выполнении команды XCOPY возникла ошибка!

 

В операторе IF ERRORLEVEL … можно также применять операторы сравнения чисел, приведенные в таблице 2. Например:

 

IF ERRORLEVEL LEQ 1 GOTO Case1

 

Примечание: Иногда более удобным для работы с кодами завершения программ может оказаться использование переменной %ERRORLEVEL%. (строковое представление текущего значения кода ошибки ERRORLEVEL).

 

Проверка версии реализации расширенной обработки команд

 

Наконец, для определения внутреннего номера версии текущей реализации расширенной обработки команд применяется оператор IF в следующем виде:

 

IF CMDEXTVERSION число команда1 [ELSE команда2]

 

Здесь условие CMDEXTVERSION применяется подобно условию ERRORLEVEL, но число сравнивается с вышеупомянутым внутренним номером версии. Первая версия имеет номер 1. Номер версии будет увеличиваться на единицу при каждом добавлении существенных возможностей расширенной обработки команд. Если расширенная обработка команд отключена, условие CMDEXTVERSION никогда не бывает истинно.

 

Организация циклов

 

В командных файлах для организации циклов используются несколько разновидностей оператора FOR, которые обеспечивают следующие функции:

 

· выполнение заданной команды для всех элементов указанного множества;

· выполнение заданной команды для всех подходящих имен файлов;

· выполнение заданной команды для всех подходящих имен каталогов;

· выполнение заданной команды для определенного каталога, а также всех его подкаталогов;

· получение последовательности чисел с заданными началом, концом и шагом приращения;

· чтение и обработка строк из текстового файла;

· обработка строк вывода определенной команды.

 

Цикл FOR … IN … DO …

 

Самый простой вариант синтаксиса команды FOR для командных файлов имеет следующий вид:

 

FOR %%переменная IN (множество)

DO команда [параметры]

 

Внимание: Перед названием переменной должны стоять именно два знака процента (%%), а не один, как это было при использовании команды FOR непосредственно из командной строки.

 

Сразу приведем пример. Если в командном файле заданы строки

 

@ECHO OFF

FOR %%i IN (Раз,Два,Три) DO ECHO %%i

 

то в результате его выполнения на экране будет напечатано следующее:

 

Раз

Два

Три

 

Параметр множество в команде FOR задает одну или более текстовых строк, разделенных запятыми, которые вы хотите обработать с помощью заданной команды. Скобки здесь обязательны. Параметр команда [параметры] задает команду, выполняемую для каждого элемента множества, при этом вложенность команд FOR на одной строке не допускается. Если в строке, входящей во множество, используется запятая, то значение этой строки нужно заключить в кавычки. Например, в результате выполнения файла с командами

 

@ECHO OFF

FOR %%i IN ("Раз,Два",Три) DO ECHO %%i

 

на экран будет выведено

 

Раз,Два

Три

 

Параметр %%переменная представляет подставляемую переменную (счетчик цикла), причем здесь могут использоваться только имена переменных, состоящие из одной буквы. При выполнении команда FOR заменяет подставляемую переменную текстом каждой строки в заданном множестве, пока команда, стоящая после ключевого слова DO, не обработает все такие строки.

 

Замечание: Чтобы избежать путаницы с параметрами командного файла %0 ‑ %9, для переменных следует использовать любые символы кроме 0 ‑ 9.

 

Параметр множество в команде FOR может также представлять одну или несколько групп файлов. Например, чтобы вывести в файл список всех файлов с расширениями txt и prn, находящихся в каталоге C:\TEXT, без использования команды DIR, можно использовать командный файл следующего содержания:

 

@ECHO OFF

FOR %%f IN (C:\TEXT\*.txt C:\TEXT\*.prn) DO ECHO %%f >> list.txt

 

При таком использовании команды FOR процесс обработки продолжается, пока не обработаются все файлы (или группы файлов), указанные во множестве.

 

Цикл FOR /D … IN … DO …

 

Следующий вариант команды FOR реализуется с помощью ключа /D:

 

FOR /D %переменная IN (набор) DO команда [параметры]

 

В случае, если набор содержит подстановочные знаки, то команда выполняется для всех подходящих имен каталогов, а не имен файлов. Скажем, выполнив следующий командный файл:

 

@ECHO OFF

CLS

FOR /D %%f IN (C:\*.*) DO ECHO %%f

 

мы получим список всех каталогов на диске C:, например:

 

C:\Arc

C:\CYR

C:\MSCAN

C:\NC

C:\Program Files

C:\TEMP

C:\TeX

C:\WINNT

 

Цикл FOR /R … IN … DO …

 

С помощью ключа /R можно задать рекурсию в команде: FOR:

 

FOR /R [[диск:]путь] %переменная IN (набор)

DO команда [параметры]

 

В этом случае заданная команда выполняется для каталога [диск:]путь, а также для всех подкаталогов этого пути. Если после ключа R не указано имя каталога, то выполнение команды начинается с текущего каталога. Например, для распечатки всех файлов с расширением txt в текущем каталоге и всех его подкаталогах можно использовать следующий пакетный файл:

 

@ECHO OFF

CLS

FOR /R %%f IN (*.txt) DO PRINT %%f

 

Если вместо набора указана только точка (.), то команда проверяет все подкаталоги текущего каталога. Например, если мы находимся в каталоге C:\TEXT с двумя подкаталогами BOOKS и ARTICLES, то в результате выполнения файла:

 

@ECHO OFF

CLS

FOR /R %%f IN (.) DO ECHO %%f

на экран выведутся три строки:

C:\TEXT\.

C:\TEXT\BOOKS\.

C:\TEXT\ARTICLES\.

 

Цикл FOR /L … IN … DO …

 

Ключ /L позволяет реализовать с помощью команды FOR арифметический цикл, в этом случае синтаксис имеет следующий: вид:

 

FOR /L %переменная IN (начало,шаг,конец) DO команда [параметры]

 

Здесь заданная после ключевого слова IN тройка (начало,шаг,конец) раскрывается в последовательность чисел с заданными началом, концом и шагом приращения. Так, набор (1,1,5) раскрывается в (1 2 3 4 5), а набор (5,-1,1) заменяется на (5 4 3 2 1). Например, в результате выполнения следующего командного файла:

 

@ECHO OFF

CLS

FOR /L %%f IN (1,1,5) DO ECHO %%f

 

переменная цикла %%f пробежит значения от 1 до 5, и на экране напечатаются пять чисел:

 

 

Числа, получаемые в результате выполнения цикла FOR /L, можно использовать в арифметических вычислениях. Рассмотрим командный файл my.bat следующего содержания:

 

@ECHO OFF

CLS

FOR /L %%f IN (1,1,5) DO CALL :2 %%f

GOTO :EOF

:2

SET /A M=10*%1

ECHO 10*%1=%M%

 

В третьей строке в цикле происходит вызов нового контекста файла my.bat с текущим значением переменной цикла %%f в качестве параметра командной строки, причем управление передается на метку :2 (см. описание CALL в разделе «Изменения в командах перехода»). В шестой строке переменная цикла умножается на десять, и результат записывается в переменную M. Таким образом, в результате выполнения этого файла выведется следующая информация:

 

10*1=10

10*2=20

10*3=30

10*4=40

10*5=50

 

Цикл FOR /F … IN … DO …

 

Самые мощные возможности (и одновременно самый запутанный синтаксис) имеет команда: FOR с ключом /F:

 

FOR /F ["ключи"] %переменная IN (набор)

DO команда [параметры]

 

Здесь параметр набор содержит имена одного или нескольких файлов, которые по очереди открываются, читаются и обрабатываются. Обработка состоит в чтении файла, разбиении его на отдельные строки текста и выделении из каждой строки заданного числа подстрок. Затем найденная подстрока используется в качестве значения переменной при выполнении основного тела цикла (заданной команды).

По умолчанию ключ /F выделяет из каждой строки файла первое слово, очищенное от окружающих его пробелов. Пустые строки в файле пропускаются. Необязательный параметр "ключи" служит для переопределения заданных по умолчанию правил обработки строк. Ключи представляют собой заключенную в кавычки строку, содержащую приведенные в таблице 3 ключевые слова:

 

Таблица 3. Ключи в команде FOR /F

Ключ	Описание
EOL=C	Определение символа комментариев в начале строки (допускается задание только одного символа)
SKIP=N	Число пропускаемых при обработке строк в начале файла
DELIMS=XXX	Определение набора разделителей для замены заданных по умолчанию пробела и знака табуляции
TOKENS=X,Y,M-N	Определение номеров подстрок, выделяемых из каждой строки файла и передаваемых для выполнения в тело цикла

 

При использовании ключа TOKENS=X,Y,M-N создаются дополнительные переменные. Формат M-N представляет собой диапазон подстрок с номерами от M до N. Если последний символ в строке TOKENS= является звездочкой, то создается дополнительная переменная, значением которой будет весь текст, оставшийся в строке после обработки последней подстроки.

 

Разберем применение этой команды на примере пакетного файла parser.bat, который производит разбор файла myfile.txt:

 

@ECHO OFF

IF NOT EXIST myfile.txt GOTO :NoFile

FOR /F "EOL=; TOKENS=2,3* DELIMS=, " %%i IN

(myfile.txt) DO @ECHO %%i %%j %%k

GOTO :EOF

:NoFile

ECHO Не найден файл myfile.txt!

 

Здесь во второй строке производится проверка наличия файла myfile.txt; в случае отсутствия этого файла выводится предупреждающее сообщение. Команда FOR в третьей строке обрабатывает файл myfile.txt следующим образом:

 

Пропускаются все строки, которые начинаются с символа точки с запятой (EOL=;).

 

Вторая и третья подстроки из каждой строки передаются в тело цикла, причем подстроки разделяются пробелами (по умолчанию) и/или запятыми (DELIMS=,).

 

В теле цикла переменная %%i используется для второй подстроки, %%j ‑ для третьей, а %%k получает все оставшиеся подстроки после третьей.

 

В нашем примере переменная %%i явно описана в инструкции FOR, а переменные %%j и %%k описываются неявно с помощью ключа TOKENS=. Например, если в файле myfile.txt были записаны следующие три строки:

 

ААА ББББ ВВВВ,ГГГГГ ДДДД

ЕЕЕЕЕ,ЖЖЖЖ ЗЗЗЗ

;КККК ЛЛЛЛЛ МММММ

 

то в результате выполнения пакетного файла parser.bat на экран выведется следующее:

 

ББББ ВВВВ ГГГГГ ДДДД

ЖЖЖЖ ЗЗЗЗ

 

Замечание: Ключ TOKENS= позволяет извлечь из одной строки файла до 26 подстрок, поэтому запрещено использовать имена переменных, начинающиеся не с букв английского алфавита (a–z). Следует помнить, что имена переменных FOR являются глобальными, поэтому одновременно не может быть активно более 26 переменных.

 

Команда FOR /F также позволяет обработать отдельную строку. Для этого следует ввести нужную строку в кавычках вместо набора имен файлов в скобках. Строка